My Little Scripts - asp-calendar.asp

Scripts.com - Get the best scripts NOW!
HotScripts.com - Over 10 web rings.
more links...

Index News Samples Downloads E-Mail me Forum Sign Up

ASP-CALENDAR.ASP

calendar() displays a calendar page of the chosen month and year. The function takes a date string as its only parameter. For the current server date to be used, a null must be passed.

These are the ASP and the ASP.NET versions of calendar.php. It was a little harder to translate than php-calendar.php, due to the difference in the vbs date functions.

<%
function calendar(today)
         if isnull(today) then
            today = date
         end if

         today = DateValue(today)

         todays_day = day(today)
         todays_month = month(today)
         todays_year = year(today)

         month_names = Array("January", _
                             "February", _
                             "March", _
                             "April", _
                             "May", _
                             "June", _
                             "July", _
                             "August", _
                             "September", _
                             "October", _
                             "November", _
                             "December")

         this_month = datevalue(todays_month & "/1/" & todays_year)
         next_month = datevalue(dateadd("m", 1, todays_month &  "/1/" & todays_year))

         'Find out when this month starts and ends.
         first_week_day = weekday(this_month) - 1

         days_in_this_month = datediff("d", this_month, next_month)

         calendar_html = "<table style=""background-color:666699; color:ffffff;"">"

         calendar_html = calendar_html & _
                         "<tr><td colspan=""7"" align=""center"" style=""background-color:9999cc; color:000000;"">" & _
                         month_names(todays_month - 1) & " " & todays_year & "</td></tr>"

         calendar_html = calendar_html & "<tr>"

         'Fill the first week of the month with the appropriate number of blanks.
         for week_day = 0 to first_week_day - 1
             calendar_html = calendar_html & "<td style=""background-color:9999cc; color:000000;""> </td>"
         next

         week_day = first_week_day
         for day_counter = 1 to days_in_this_month
             week_day = week_day mod 7

             if week_day = 0 then
                calendar_html = calendar_html & "</tr><tr>"
             end if

             'Do something different for the current day.
             if todays_day = day_counter then
                calendar_html = calendar_html & "<td align=""center""><b>" & day_counter & "</b></td>"
             else
                calendar_html = calendar_html & _
                                "<td align=""center"" style=""background-color:9999cc; color:000000;""> " & _
                                day_counter & " </td>"
             end if

             week_day = week_day + 1
         next

         calendar_html = calendar_html & "</tr>"
         calendar_html = calendar_html & "</table>"

         Calendar = calendar_html
end function
%>

<script language="VB" runat="server">
Function calendar(ByVal today As Date) As String
         If IsNothing(today) Then
            today = DateTime.Now
         End If

         today = DateValue(today)

         todays_day = Day(today)
         todays_month = Month(today)
         todays_year = Year(today)

         Dim month_names(12) As String

         month_names(0) = "January"
         month_names(1) = "February"
         month_names(2) = "March"
         month_names(3) = "April"
         month_names(4) = "May"
         month_names(5) = "June"
         month_names(6) = "July"
         month_names(7) = "August"
         month_names(8) = "September"
         month_names(9) = "October"
         month_names(10) = "November"
         month_names(11) = "December"

         this_month = DateValue(todays_month & "/1/" & todays_year)
         next_month = DateValue(DateAdd("m", 1, todays_month & "/1/" & todays_year))

         'Find out when this month starts and ends.
         first_week_day = Weekday(this_month) - 1

         days_in_this_month = DateDiff("d", this_month, next_month)

         calendar_html = "<table style=""background-color:666699; color:ffffff;"">"

         calendar_html = calendar_html & _
                         "<tr><td colspan=""7"" align=""center"" style=""background-color:9999cc; color:000000;"">" & _
                         month_names(todays_month - 1) & " " & todays_year & "</td></tr>"

         calendar_html = calendar_html & "<tr>"

         'Fill the first week of the month with the appropriate number of blanks.
         For week_day_counter = 0 To first_week_day - 1
             calendar_html = calendar_html & "<td style=""background-color:9999cc; color:000000;""> </td>"
         Next

         week_day = first_week_day
         For day_counter = 1 To days_in_this_month
             week_day = week_day Mod 7

             If week_day = 0 Then
                 calendar_html = calendar_html & "</tr><tr>"
             End If

             'Do something different for the current day.
             If todays_day = day_counter Then
                 calendar_html = calendar_html & "<td align=""center""><b>" & day_counter & "</b></td>"
             Else
                 calendar_html = calendar_html & _
                                 "<td align=""center"" style=""background-color:9999cc; color:000000;""> " & _
                                 day_counter & " </td>"
             End If

             week_day = week_day + 1
         Next

         calendar_html = calendar_html & "</tr>"
         calendar_html = calendar_html & "</table>"

         calendar = calendar_html
End Function
</script>