INCLUDE.ASP

Although it is possible to use include files in ASP

I found that it was not possible to do so during runtime. VBScript seems to be lacking an include function. So I wrote these 3 functions: asp_html_include(), asp_vbs_include(), and vbs_include(). The reason for this is that I could not create a function that executed VBS AND displayed HTML.

<%= asp_html_include(file) %>
will display the html content of file. In order for the function to work without the =, you would have to place a Response.Write(FileContent) at the end of the function.
asp_vbs_include(file) will execute the VBScript code inside file. Note that file must only contain VBS, no ASP tags or HTML. vbs_include() is just like asp_vbs_include() but made for command line VBScript files, it also happens to be the fuction that I derived the other two from.

<%
function asp_html_include(FileName)
         dim FileSystem, TextStream, FileContent

         Set FileSystem = CreateObject("Scripting.FileSystemObject")

         path = Request.ServerVariables("PATH_TRANSLATED")
         path = left(path, inStrRev(path, "\"))

         Set TextStream = FileSystem.OpenTextFile(path & FileName, 1)
         FileContent = TextStream.ReadAll
         TextStream.Close

         asp_html_include = FileContent
end function
%>

<%
function asp_vbs_include(FileName)
         dim FileSystem, TextStream, FileContent

         Set FileSystem = CreateObject("Scripting.FileSystemObject")

         path = Request.ServerVariables("PATH_TRANSLATED")
         path = left(path, inStrRev(path, "\"))

         Set TextStream = FileSystem.OpenTextFile(path & FileName, 1)
         FileContent = TextStream.ReadAll
         TextStream.Close

         ExecuteGlobal(FileContent)
end function
%>

<%
function vbs_include(FileName)
         dim FileSystem, TextStream, FileContent

         Set FileSystem = CreateObject("Scripting.FileSystemObject")

         Set TextStream = FileSystem.OpenTextFile(FileName, 1)
         FileContent = TextStream.ReadAll
         TextStream.Close

         ExecuteGlobal(FileContent)
end function
%>